Công thức tìm vị trí ô đầu tiên, ô cuối cùng theo điều kiện Thảo luận trong 'Hàm và công thức Excel' bắt đầu bởi hoangdanh282vn, 30 Tháng bảy 2008.

Công thức tìm vị trí ô đầu tiên, ô cuối cùng theo điều kiện

Thảo luận trong 'Hàm và công thức Excel' bắt đầu bởi hoangdanh282vn, 30 Tháng bảy 2008.

A .Tìm vị trí ô đầu tiên, ô cuối cùng trong cùng một cột thỏa điều kiện


1. Dòng đầu tiên khác rỗng :

PHP:

=SUMPRODUCT(MATCH(TRUE,A$1:A$65535<>"",0))

2. Dòng đầu tiên khác rỗng với dữ liệu chuỗi :

PHP:

=MATCH("*",A:A,0)

3. Dòng đầu tiên khác rỗng với dữ liệu số :

PHP:

{=MIN(IF(ISNUMBER(A1:A65535),ROW(A1:A65535)))}

4. Dòng cuối cùng khác rỗng :

PHP:

=SUMPRODUCT(MAX(((A$1:A$65535<>"")*ROW(A$1:A$65535))))

=MAX(MATCH(9.99999999999999E+307,A:A),MATCH(REPT("z",255),A:A))

5. Dòng cuối cùng khác rỗng với dữ liệu số :

PHP:

=MATCH(9.99999999999999E+307,A:A)

6. Dòng cuối cùng khác rỗng với dữ liệu chuỗi :

PHP:

=MATCH(REPT("z",255),A:A)

B .Tìm giá trị ô đầu tiên, ô cuối cùng trong cùng một cột thỏa điều kiện


1. Giá trị ô đầu tiên khác rỗng :

PHP:

=INDEX(A:A,SUMPRODUCT(MATCH(TRUE,A$1:A$65535<>"",0)))

2. Giá trị ô đầu tiên khác rỗng với dữ liệu chuỗi:

PHP:

=INDEX(A:A,MATCH("*",A:A,0))

3. Giá trị ô đầu tiên khác rỗng với dữ liệu số:

PHP:

{=INDEX(A:A,MIN(IF(ISNUMBER(A1:A65535),ROW(A1:A65535))))}

4. Giá trị ô cuối cùng khác rỗng :

PHP:

=INDEX(A:A,MAX(MATCH(9.99999999999999E+307,A:A),MATCH(REPT("z",255),A:A)))

5. Giá trị ô cuối cùng khác rỗng với dữ liệu số :

PHP:

=LOOKUP(9.99999999999999E+307,A:A)

6. Giá trị ô cuối cùng khác rỗng với dữ liệu chuỗi :

PHP:

=LOOKUP(REPT("z",255),A:A)

C. Tìm vị trí của ô đầu tiên, ô cuối cùng có chứa dữ liệu tìm kiếm :


Row of Lastcell with lookup_value :

PHP:

{=MAX(((A1:A100=lookup_value)*ROW(A1:A100)))} press Ctrl+Shif+Enter

Row of Firstcell with lookup_value :

PHP:

{=SMALL(((A1:A100=lookup_value)*ROW(A1:A100)),SUMPRODUCT(--NOT((A1:A100=lookup_value)))+1)} press Ctrl+Shif+Enter



Tương tự cho dòng

Share on Google Plus

About sorftphanmem